@echo off
title %~nx0
if exist dd.exe set dd_exe=ok
if exist .\dd-0.5\dd.exe (
set dd_exe=ok
set path=%cd%\dd-0.5;%path%
)

if exist gzip.exe set gzip_exe=ok
if exist .\texinst\gzip.exe (
set gzip_exe=ok
set path=%cd%\texinst;%path%
)

:ASK
set target=
cls
echo:
echo     ==============================================================
echo            ドライブレターを入力 !
echo                     * 99 で終了.
echo     ==============================================================
echo:
set /p target=    [A,B,99] : 
echo:
if "%target%"=="99" GOTO :EOF
if /i "%target%"=="a" GOTO CHECK
if /i "%target%"=="b" GOTO CHECK
GOTO ASK

:CHECK
dir /a %target%:\ >nul 2>&1
if ERRORLEVEL 1 (
echo:
echo     ! 存在しない？ フロッピーが空かな？
echo.
echo     *** 何かキーを押すと戻ります *** 
echo.
pause >nul
GOTO ASK
)

if not defined dd_exe GOTO DEL_FILE

REM ##########################################################
REM ### バックアップイメージ作成
REM ##########################################################
echo:
echo      **********************************************
echo       * バックアップ FD イメージ作成中....
echo      **********************************************
echo:
dd if=\\.\%target%: of=Fdos_SCL.img bs=10k count=144 --progress
echo:
echo:

REM ##########################################################
REM ### 不要ファイル削除
REM ##########################################################
:DEL_FILE
if exist %target%:\driver\RAMFD.SYS (
del /f %target%:\driver\RAMFD.SYS >nul
if not ERRORLEVEL 1 echo       * %target%:\driver\RAMFD.SYS を 削除..
)

if exist %target%:\grub.exe (
del /f %target%:\grub.exe >nul
if not ERRORLEVEL 1 echo       * %target%:\grub.exe を 削除...
)

if exist %target%:\menu.lst (
del /f %target%:\menu.lst >nul
if not ERRORLEVEL 1 echo       * %target%:\menu.lst を 削除...
)
echo:
echo:

REM ##########################################################
REM ### ファイル置換コピー
REM ##########################################################
:COPYFILE
set File_01=autoexec.bat
set File_02=config.sys
set File_03=menu.txt
set File_04=menu_usb.txt
set File_05=bin\bgrescue.bat
set File_06=bin\copyb.bat
set File_07=bin\insert.bat
set File_08=bin\other.bat
set File_09=bin\start.bat
set File_10=bin_usb\other.bat
set File_11=bin_usb\start.bat

for /f "usebackq tokens=2 delims==" %%x in (`set File_`) do (
copy /y %%x %target%:\%%x >nul
if not ERRORLEVEL 1 echo       * %%x を %target%:\%%x へコピー...
)

echo:
if not defined dd_exe GOTO DONE

REM ##########################################################
REM ### FDイメージ 作成
REM ##########################################################
echo:
echo      **********************************************
echo       * FD イメージ作成中....
echo      **********************************************
echo:
dd if=\\.\%target%: of=Fdos_SCL2.img bs=10k count=144 --progress
echo:
echo:

if not defined gzip_exe GOTO DONE

REM ##########################################################
REM ### gzip イメージ 作成
REM ##########################################################
echo:
echo      **********************************************
echo       * gzip イメージ作成中....
echo      **********************************************
echo:
gzip -fc Fdos_SCL2.img > fdos_scl.img.gz
echo:
if not ERRORLEVEL 1 (
echo       * gzipイメージ - fdos_scl.img.gz を作成しますた！
echo:
) else (
echo:
echo       ！ gzipイメージ 作成失敗しますた.....orz
echo:
)
echo:

REM ##########################################################
REM ### DONE
REM ##########################################################
:DONE
echo              ===========================================
echo:
echo               * おｋ !
echo:
echo                        ...エラーなければですけど...
echo:
echo              ===========================================
echo:
echo                   *** 何かキーを押すと閉じます *** 
pause >nul