@echo off
cdd %ramdrv%\
REM Copy all files to RAM Drive
:docopy
if exist A:\end.txt GOTO done
pause Insert next floppy and press a key...
copy a:\LDFD*.*
GOTO docopy

:done
REM Now reconstruct the zipfile
for %%f in (LDFDR*.*) do call appld.bat %%f
del ldfdr*.*
unzip ldfd

cls
set kernel=
set initrd=
set options=
set param1=

REM ############     find kernel       #############

for %%x in (altker64,altker32,rescuecd,vmlinuz1,bzImage1,bzImage,kernel,vmlinuz,linux) do if exist %ramdrv%\%%x set kernel=%%x
if "%kernel%"=="" GOTO NOKERNEL

echo.
echo kernel found ... filename = %kernel%
echo.

REM ############     find initrd       #############

for %%x in (initram,initram.igz,initrd1.img,initrfs.gz,miniroot,miniroot.gz,miniroot.img,minird,minird.img,minird.gz,minirt,minirt.img,minirt.gz,initrd,initrd.gz,initrd.img,,,) do if exist %ramdrv%\%%x set initrd=%%x
if "%initrd%"=="" GOTO NOINITRD

echo.
echo initrd found ... filename = %initrd%
echo.

:OPT
REM ############  find options.txt     #############
echo.
echo ========  [ options.txt ]  Directory ?  ========
echo.
echo       1. ====    Floppy = A:     ====
echo       2. ====    Ramdrive        ====
echo       3. ====       none         ====
echo.
echo ================================================
%ramdrv%\freedos\choice /C:123X Type Number:

if ERRORLEVEL 4 GOTO END
if ERRORLEVEL 3 GOTO NONE
if ERRORLEVEL 2 GOTO RAMD
if ERRORLEVEL 1 GOTO FLOPPY

:NONE
set options=
GOTO BOOT

:RAMD
if exist .\options.txt set options=.
if "%options%"=="" pause options.txt not found !!! press any key to continue ...
if "%options%"=="" GOTO OPT
echo.
echo options.txt found ...
GOTO BOOT

:FLOPPY
if exist a:\options.txt set options=a:
if "%options%"=="" pause options.txt not found !!! press any key to continue
if "%options%"=="" GOTO OPT
echo.
echo options.txt found ...
GOTO BOOT

:BOOT
REM ############       linld boot      ############
echo.
echo ========  [ tuika no parameter ] arimasuka  ?  ========
set /p param1=
echo.

if "%options%"=="" GOTO NOOPT
if not "%param1%"=="" GOTO BOOT2

%ramdrv%\freedos\linld image=%kernel% initrd=%initrd% vga=normal cl=@%options%\options.txt
if ERRORLEVEL 1 GOTO ERROR

:BOOT2
copy %options%\options.txt %options%\temp.txt
echo   %param1%>>%options%\temp.txt

%ramdrv%\freedos\linld image=%kernel% initrd=%initrd% vga=normal cl=@%options%\temp.txt
if ERRORLEVEL 1 GOTO ERROR

:NOOPT
if not "%param1%"=="" GOTO NOOPT2

%ramdrv%\freedos\linld image=%kernel% initrd=%initrd%
if ERRORLEVEL 1 GOTO ERROR

:NOOPT2

%ramdrv%\freedos\linld image=%kernel% initrd=%initrd% "cl=%param1%"
if ERRORLEVEL 1 GOTO ERROR

REM ############        error!         ############
:NOKERNEL
echo.
echo Can't find kernel !!!
pause
GOTO ERROR

:NOINITRD
echo.
echo Can't find initrd !!!
pause
GOTO ERROR

:ERROR
echo.
echo error !!!
echo.
echo       ========================== linld command ===========================
echo       linld image=filename initrd=filename vga=normal cl=@A:\options.txt
echo       linld image=filename initrd=filename vga=normal "cl=nnn=xxx mmm=xxx"
echo       ====================================================================
echo.
echo       Please Retry !
echo.
GOTO END

:END