@echo off
REM ##################################################################################
REM ###  edit by yassy http://www10.plala.or.jp/palm84/
REM ###  XBOOT の iso をリメイクするバッチファイルです
REM ###  http://d.hatena.ne.jp/palm84/20130727/1374854104
REM ###  http://d.hatena.ne.jp/palm84/20120307/1331133210
REM ###  http://www10.plala.or.jp/palm84/liveusb_creator.html
REM ###  https://www.palm84.com/entry/liveusb_creator
REM ###  http://www10.plala.or.jp/palm84/archives/commandline/backup/xboot_remake_iso.bat.txt
REM  https://eu7w9wsmf6a74xyjdfzl3q-on.drv.tw/archives/commandline/backup/xboot_remake_iso.bat.txt
REM ##################################################################################

title XBOOT の iso をリメイクするYO！
pushd %~dp0
REM ### mkisofs.exe の path をチェック
if exist "%ProgramFiles(x86)%\cdrtools\mkisofs.exe" set "CDRTools_Path=%ProgramFiles(x86)%\cdrtools"
if exist "%ProgramFiles%\cdrtools\mkisofs.exe" set "CDRTools_Path=%ProgramFiles%\cdrtools"
if exist mkisofs.exe (if exist cygwin1.dll set "CDRTools_Path=%cd%")
if not defined CDRTools_Path GOTO NOFILE
path=%CDRTools_Path%;%path%
REM path
REM pause >nul

REM ### ドライブのルートは禁止
pushd ..\
for /f "usebackq delims=" %%I in ('%cd%') do (if /i "%cd%"=="%%~dI\" GOTO DANGER)

REM ### チェック boot\syslinux\isolinux.bin
if not exist boot\syslinux\isolinux.bin GOTO NO_BIN

REM ### XBOOT の一つ上のディレクトリにiso作成
set iso=..\xboot-remake.iso
REM ## iso作成先を直接指定
REM ## set iso=D:\VMware\LiveCD\iso\xboot-remake.iso

REM ## iso作成先をフルパスで設定
for /f "delims=" %%I in ("%iso%") do set iso=%%~fI
echo:
echo:

REM #####################################
REM ### START
REM #####################################
:START
cls
echo:
echo         **************************************************************
echo         =====          XBOOT の iso をリメイクしますん！         =====
echo         **************************************************************
echo         *****   %iso%
echo         *****    作成します！ よろしおますか？
echo         *****    * 同名ファイルあらばリネームするです
echo         **************************************************************
echo:
echo                   続行しますか？ 中断は xボタン or Ctrl-C
echo:
echo                     *** 何かキーを押すと続行します *** 
pause >nul
echo:
echo:

REM #####################################
REM ### 既存ファイルのリネーム
REM #####################################
:BACKNAME
if not exist "%iso%" GOTO MAKEISO

for /f "delims=" %%I in ("%iso%") do set bt=%%~tI
set bt=%bt: =%
set bt=%bt:~-13,2%%bt:~-10,2%%bt:~-7,2%_%bt:~-5,2%%bt:~-2,2%
for /f "delims=" %%I in ("%iso%") do set backname=%%~nI_%bt%%%~xI
ren "%iso%" %backname%
if ERRORLEVEL 1 GOTO ERROR

REM #####################################
REM ### MAKEISO
REM #####################################
:MAKEISO
mkisofs.exe -no-bak -iso-level 4 -publisher http://sites.google.com/site/shamurxboot -no-emul-boot -boot-load-size 4 -hide boot.catalog -allow-lowercase -max-iso9660-filenames -r -J -joliet-long -boot-info-table -b boot/syslinux/isolinux.bin -o "%iso%" .

if ERRORLEVEL 1 GOTO ERROR
GOTO DONE

REM #####################################
REM ### NOFILE
REM #####################################
:NOFILE
echo:
for %%x in (mkisofs.exe,cygwin1.dll) do (
if not exist %%x (
echo                ！！！ %%x がないでござる          ...orz
echo                  * makeiso ディレクトリに置いてくだされ...
echo                  * または CDR-Tools をインスコしてくださいませ...
))
GOTO END

REM #####################################
REM ### NO_BIN
REM #####################################
:NO_BIN
echo:
echo                ！！！ isolinux.bin がないでござる          ...orz
echo:
echo                 * boot\syslinux\ に置いてくだされ...
echo:
GOTO END

REM #####################################
REM ### DANGER
REM #####################################
:DANGER
echo:
echo        ！ ドライブルートはだめにしてます。。。すみませぬ....
echo:
GOTO END

REM #####################################
REM ### ERROR
REM #####################################
:ERROR
echo:
echo        ！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！
echo        ！！！           エラー出ますた！ orz...                ！！！
echo        ！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！！
echo:
GOTO END

REM #####################################
REM ### DONE
REM #####################################
:DONE
echo:
echo      ******************************************************************
echo      ************                Done ！                   ************
echo      ******************************************************************
echo:
GOTO END

REM #####################################
REM ### END
REM #####################################
:END
echo:
echo                     *** 何かキーを押すと閉じます *** 
pause >nul