@echo off
title %~nx0
:ASK_FILE
cls
echo:
echo         **************************************************************
echo         *                                                            *
echo         * === * ファイル名を指定して検索...(※C,Dドライブ)       === *
echo         * === * Filever.exe でバージョン情報などを書き出し...    === *
echo         *                                                            *
echo         * ===       ! ファイル名完全一致のみ検索します !         === *
echo         *                                                            *
echo         * ===   部分一致も検索するにはワイルドカード [.*] 指定   === *
echo         * ===        * 例 : flash.*.ocx                          === *
echo         * ===        * 例 : regedit.*                            === *
echo         * ===        * 例 : .*reg.exe                            === *
echo         *                                                            *
echo         * ===      複数ファイル指定は、スペース区切りで...       === *
echo         *                                                            *
echo         *                    *** 中断は 999 ***                      *
echo         **************************************************************
echo:
set /p filename= ファイル名を入力 : 
echo:
if defined filename set filename=%filename:"=%
if "%filename%"=="999" GOTO :EOF
if "%filename%"=="" GOTO ASK_FILE
set log=%filename:.*=-%
set log=%log: =_%
set log=Filever_%log%.txt
> "%log%" echo =========================================================
>>"%log%" echo %date% %time% -- %filename%
>>"%log%" echo =========================================================
for /f "usebackq delims=" %%I in (`dir /a-d/b/s C:\ ^| findstr /i /e "%filename%"`) do (
echo %%~nxI | findstr /i /b "%filename%" >nul
if not ERRORLEVEL 1 (
>>"%log%" echo ---------------------------------------------------------
>>"%log%" echo %%I
>>"%log%" echo ---------------------------------------------------------
>>"%log%" filever /v "%%I"
>>"%log%" echo:)
)
if not exist D:\ GOTO SHOW_LOG
for /f "usebackq delims=" %%I in (`dir /a-d/b/s D:\ ^| findstr /i /e "%filename%"`) do (
echo %%~nxI | findstr /i /b "%filename%" >nul
if not ERRORLEVEL 1 (
>>"%log%" echo ---------------------------------------------------------
>>"%log%" echo %%I
>>"%log%" echo ---------------------------------------------------------
>>"%log%" filever /v "%%I"
>>"%log%" echo:)
)
:SHOW_LOG
start "" "%log%"