@echo off
title %~nx0
REM ********************************************************************
REM   * ファイル名一覧書き出し
REM  http://www10.plala.or.jp/palm84/commandline.html
REM  http://www10.plala.or.jp/palm84/archives/commandline/backup/Dir_Filename_sendto.bat.txt
REM  https://eu7w9wsmf6a74xyjdfzl3q-on.drv.tw/archives/commandline/backup/Dir_Filename_sendto.bat.txt
REM ********************************************************************
if "%~1"=="" GOTO NO_PARAM
for %%x in ("%~a1") do set check_dir=%%~x
if /i not "%check_dir:~0,1%"=="d" GOTO FILEYAN
pushd %~dp0

REM #####################################
REM ### ログのバックアップ
REM #####################################
REM set Backup=

REM #####################################
REM ### ログファイルの指定
REM #####################################
set log=%cd%\%~n0_log1.txt

REM ログを指定ディレクトリに作成する場合
REM set log=%~f1\%~n0_log1.txt

REM #####################################
REM ### 日付
REM #####################################
pushd %~f1
echo:
echo      ==============================================================
echo       %cd%
echo      ==============================================================
echo:
REM pause >nul
> "%log%" echo --------------------------------------------------------------
>>"%log%" echo %date% %time:~-11,5%
>>"%log%" echo ==============================================================
>>"%log%" echo %~f1
>>"%log%" echo ==============================================================
>>"%log%" echo:

REM #####################################
REM ### ファイル名のみ
REM #####################################
if defined log_target (
>>"%log%" (dir /a-d/b | findstr /v %logname%)
) else (
>>"%log%" dir /a-d/b
)
>>"%log%" echo:
>>"%log%" echo -------------------------------------------------------------
>>"%log%" echo:

REM #####################################
REM ### フルパス ファイル名のみ
REM #####################################
for /f "usebackq delims=" %%I in (`dir /a-d/b`) do (
if defined log_target (
>>"%log%" (echo %%~fI | findstr /v %logname%)
) else (
>>"%log%" echo %%~fI
)
)

>>"%log%" echo:
>>"%log%" echo -------------------------------------------------------------
>>"%log%" echo:

REM #####################################
REM ### dir /a-d の出力
REM #####################################
>>%log% dir /a-d

if defined Backup (
copy "%log%" "%Backup%\"
)
start "" "%log%"
GOTO :EOF

REM #####################################
REM ### NO_PARAM
REM #####################################
:NO_PARAM
echo:
echo        ==============================================================
echo                    ！引数（ファイル指定）がないですYO！
echo        ==============================================================
echo:
GOTO END

REM #####################################
REM ### FILEYAN
REM #####################################
:FILEYAN
echo:
echo        ==============================================================
echo         ！ %~1 
echo:
echo         ！      ... はディレクトリちゃいます
echo        ==============================================================
echo:
GOTO END

REM #####################################
REM ### END
REM #####################################
:END
echo:
echo                     *** 何かキーを押すと閉じます *** 
pause >nul